cmake_minimum_required(VERSION 3.27)

project(bayesnet
  VERSION 1.1.1
  DESCRIPTION "Bayesian Network and basic classifiers Library."
  HOMEPAGE_URL "https://github.com/rmontanana/bayesnet"
  LANGUAGES CXX
)

set(CMAKE_CXX_STANDARD 17)
cmake_policy(SET CMP0135 NEW)

find_package(Torch CONFIG REQUIRED)
find_package(fimdlp CONFIG REQUIRED)
find_package(nlohmann_json CONFIG REQUIRED)
find_package(folding CONFIG REQUIRED)

# Global CMake variables
# ----------------------
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED            ON)
set(CMAKE_CXX_EXTENSIONS                  OFF)
set(CMAKE_EXPORT_COMPILE_COMMANDS          ON)
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${TORCH_CXX_FLAGS}")
SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pthread")
set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -fprofile-arcs -ftest-coverage -fno-elide-constructors")
set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -Ofast")
if (NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
    set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -fno-default-inline")
endif()

# Options
# -------
option(ENABLE_CLANG_TIDY "Enable to add clang tidy"              OFF)
option(ENABLE_TESTING "Unit testing build"                       OFF)
option(CODE_COVERAGE "Collect coverage from test library"        OFF)
option(INSTALL_GTEST "Enable installation of googletest"         OFF)

add_subdirectory(config)

if (ENABLE_CLANG_TIDY)
    include(StaticAnalyzers) # clang-tidy
endif (ENABLE_CLANG_TIDY)

# Add the library
# ---------------
include_directories(
    ${bayesnet_SOURCE_DIR}
    ${CMAKE_BINARY_DIR}/configured_files/include
)

file(GLOB_RECURSE Sources "bayesnet/*.cc")

add_library(bayesnet ${Sources})
target_link_libraries(bayesnet fimdlp::fimdlp folding::folding "${TORCH_LIBRARIES}")

# Testing
# -------
if (CMAKE_BUILD_TYPE STREQUAL "Debug")
    MESSAGE("Debug mode")
    set(ENABLE_TESTING ON)
    set(CODE_COVERAGE ON)
endif (CMAKE_BUILD_TYPE STREQUAL "Debug")
if (ENABLE_TESTING)
    MESSAGE(STATUS "Testing enabled")
    find_package(Catch2 CONFIG REQUIRED)
    find_package(arff-files CONFIG REQUIRED)
    enable_testing()
    include(CTest)
    add_subdirectory(tests)
else(ENABLE_TESTING)
    message("Release mode")
endif (ENABLE_TESTING)

# Installation
# ------------
include(CMakePackageConfigHelpers)
write_basic_package_version_file(
    "${CMAKE_CURRENT_BINARY_DIR}/bayesnetConfigVersion.cmake"
    VERSION ${PROJECT_VERSION}
    COMPATIBILITY AnyNewerVersion
)

configure_package_config_file(
    ${CMAKE_CURRENT_SOURCE_DIR}/bayesnetConfig.cmake.in
    "${CMAKE_CURRENT_BINARY_DIR}/bayesnetConfig.cmake"
    INSTALL_DESTINATION share/bayesnet)

install(TARGETS bayesnet
        EXPORT bayesnetTargets
        ARCHIVE DESTINATION lib
        LIBRARY DESTINATION lib
        CONFIGURATIONS Release)

install(DIRECTORY bayesnet/ 
    DESTINATION include/bayesnet 
    FILES_MATCHING 
    CONFIGURATIONS Release 
    PATTERN "*.h")
install(FILES ${CMAKE_BINARY_DIR}/configured_files/include/bayesnet/config.h 
    DESTINATION include/bayesnet 
    CONFIGURATIONS Release)

install(EXPORT bayesnetTargets
        FILE bayesnetTargets.cmake
        NAMESPACE bayesnet::
        DESTINATION share/bayesnet)

install(FILES
    "${CMAKE_CURRENT_BINARY_DIR}/bayesnetConfig.cmake"
    "${CMAKE_CURRENT_BINARY_DIR}/bayesnetConfigVersion.cmake"
    DESTINATION share/bayesnet
)